4.3. 通过利用触摸传感方式，执行自动设置摆动幅度的电弧传感
4.3. 通过利用触摸传感方式，执行自动设置摆动幅度的电弧传感
生成可共同适用于如下两个工件的一个作业程序。
图 4.2 Butt触摸传感、电弧传感工件
作业环境假设如下：
焊接两个工件之间的工艺
180度平面摆动
焊接进行方向为 X+ 方向针对工件的触摸传感以Y方向进行左右传感。
假设电弧传感的参数已完成设置。
当间隔(gap)为4.0mm时，焊接速度则为7.0mm/sec。
当间隔(gap)为8.0mm时，焊接速度则为3.5mm/sec。
作业顺序如下：
1) 利用触摸传感指令，测量终点Butt部分的焊接中心位置及gap距离。
2) 利用触摸传感指令，测量始点Butt部分的焊接中心位置及gap距离。
3) 判断V10!值是否在允许范围内。当超出2.0mm ~ 10.0mm范围时则停止。
4) 将被测距离的一半分别指定为墙壁方向（左侧面）和其他方向（右侧面）的距离。
5) 当焊接速度为4.0mm/sec，8.0mm/sec时，按速度计算插值。当Gap小于4.0mm时则适用7.0mm/sec，当Gap超过8mm时则适用4.0mm/sec的固定速度。
6) 按计算出的数值自动输入摆动宽度、焊接进行速度。
7) 作业执行完毕后恢复到原本始点。
图 4.3 Butt触摸传感及电弧传感
l 示例程序如下：
~~~~~~~电弧传感程序0002.JOB~~~~~~~~~~~~~~~
'Butt电弧传感程序
'1位数：开始条件，10位数：结束条件
S1 MOVE P,S=60%,A=3,T=1 ' 1:工作始点
S2 MOVE L,S=30%,A=3,T=1 ' 2:终点触摸传感位置
TOUCHSEN TSC#=2,+TY,-TZ,5,P10,V11! ' 3:终点触摸传感，在P10中保存位置
S3 MOVE L,S=30%,A=3,T=1 ' 4:始点触摸传感位置
TOUCHSEN TSC#=3,+TY,-TZ,5,P1,V1! ' 5:始点触摸传感，在P1中保存位置
'Calc.weld speed, width according to Gap V1! 按Gap设置速度
V1!<2.0 OR V1!>10.0 THEN '超出允许范围
GOTO *Error
ELSEIF V1!<4.0 THEN '当小于4mm时则固定为7mm/sec
V3!=7.0 'Weld speed at start
ELSEIF V1!>8.0 THEN '当大于8mm时则固定为4mm/sec
V3!=4.0 'Weld speed at start
ELSE '当处于4~8mm范围内则按线性插值计算速度
V3!=(7-3.5)/(4-8)*V1!+10.5 'Linear interpolated weld speed at start
ENDIF
V4!=V1!/2.0 'left side width 'Gap的一半指定为左侧摆动幅度
V5!=V1!/2.0 'right side width 'Gap的一半指定为右侧摆动幅度
'--------------------------------------------------------
'Calc.weld speed, width according to Gap V11!
IF V11!<2.0 OR V11!>10.0 THEN '超出允许范围
GOTO *Error
ELSEIF V11!<4.0 THEN '当小于4mm时则固定为7mm/sec
V13!=7.0 'Weld speed at start
ELSEIF V11!>8.0 THEN '当大于8mm时则固定为4mm/sec
V13!=4.0 'Weld speed at start
ELSE ' 当处于4~8mm范围内按线性插值计算速度
V13!=(7-3.5)/(4-8)*V11!+10.5 ' Linear interpolated weld speed at end
ENDIF
V14!=V11!/2.0 'left side width
V15!=V11!/2.0 'right side width
'---------------------------------------------------------
S4 MOVE L,P11,S=20%,A=3,T=1 ' 6:移动到焊接始点
WEAVON WEV#=2 ' 7:开始摆动、电弧传感
ARCON ASF#=2 ' 8:开始焊接
ARC_COND L,V3!,V4!,V5!,2,400,32 ' 9:Start of weld parameter continuous change
S5 MOVE L,P10,S=60cm/min,A=3,T=1 '10:移动到焊接终点
ARC_COND L,V13!,V14!,V15!,2,400,32 '11:End of weld parameter continuous change
ARCOF ASF# '12:焊接结束
WEAVOF '13:摆动、电弧传感结束
S6 MOVE P,S=60%,A=3,T=1 '14:工作终点
END
*Error '15:偏离Gap范围时的避开位置
DO200=1 '16:为显示错误而输出信号
STOP '17:机器人停止
END
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~